write ahead log

ロールフォワード用

次の指定曜日の日付を取得する

ちょいちょい使うのでメモ.

''' <summary>
''' 指定日の次の指定曜日の日付を返す
''' </summary>
''' <param name="d">次の曜日を調べる起算日</param>
''' <param name="day">日付を得たい次の曜日</param>
''' <returns>d日から始めて次のday曜日の日付</returns>
Private Function getNextDayOfWeek(ByVal d As Date, ByVal day As System.DayOfWeek) As Date
    '定数DayOfWeekは0起算の連続した数値なので当週の曜日指定日付は
    'd.AddDays(day - d.DayOfWeek)で導出可能

    '直近のday曜日を導出してその1週間後
    Return d.AddDays(day - d.DayOfWeek).AddDays(7)
End Function

フォルダパスの組立と特殊フォルダ名の取り扱い方

パスをC:\とか指定するのは流石にないだろうと.

いい機会なのでまとめようと思う.

パスの組立

パスの取り扱いは専用のクラスが用意されている.

MS Developer Network - Pathクラス.aspx)

パスの組立はCombineメソッドを使うといい感じ.

path = System.IO.Path.Combine(path, "hoge.csv")

このメソッドはオーバーロードされていて, 4引数まで使える.

path = System.IO.Path.Combine(path, "dir1", "dir2", "dir3", "hoge.csv")

特殊フォルダの場所の取得

Windowsでよく使う特殊フォルダは取得する方法が用意されている.

Environment.GetFolderPath メソッド.aspx)

こんな感じで簡単にデスクトップのパスとかを取れる.

System.Environment.GetFolderPath(Environment.SpecialFolder.DesktopDirectory)

なのでデスクトップにファイルを保存する時も簡単.

デスクトップに"test.csv"を保存したいときにパスを作ると以下の感じ.

Dim path As String = System.IO.Path.Combine(
    System.Environment.GetFolderPath(Environment.SpecialFolder.DesktopDirectory), "test.csv")

特殊フォルダは定数になっているので必要なものを使うだけで良い.

Environment.SpecialFolder 列挙型.aspx)

余談

他にも便利なメソッドがいっぱい.

メソッド名 機能
GetExtension(String) 指定したパス文字列の拡張子を返す
GetFileName(String) 指定したパス文字列のファイル名と拡張子を返す
GetFileNameWithoutExtension(String) 指定したパス文字列のファイル名を拡張子を付けずに返す

CSVを読み込む・書き込む

簡単そうでエスケープ(,入力が必要な際のダブルクオーテーションによる例外化)処理やデリミタ変更(TSV)が以外と面倒なCSV処理.

標準ライブラリでやってみました.

書いてからEncoding指定もパラメータ化すれば良かったと思いましたが, そもそもクラス化してライブラリにした方がいいでしょうね.

読み込み

ファイル名指定

TextFieldParserを使うとファイル名も指定出来て楽.

けど, 後述するStream渡しの方が単機能になって個人的には好み.

''' <summary>
''' CSVファイル名を渡して解析し, 結果の2次元のリストを返す
''' </summary>
''' <param name="fileName">解析するCSVファイル名</param>
''' <returns>CSVの行列を含む2次元のリスト</returns>
Private Function LoadCSVFile(ByVal fileName As String) As List(Of List(Of String))
    '=========================================
    '結果返答用のリストを準備
    '=========================================
    Dim ret As New List(Of List(Of String))

    '=========================================
    'ファイル解析用にTextFieldParserを用意
    '=========================================
    'ファイル名から指定する場合
    Dim parser As New FileIO.TextFieldParser(fileName,
                             System.Text.Encoding.GetEncoding("Shift_JIS"))

    '=========================================
    'Parserの設定
    '=========================================
    '区切り文字形式指定
    parser.TextFieldType = FileIO.FieldType.Delimited
    'デリミタを指定(CSVなら, TSVならvbTab)
    parser.SetDelimiters(",")
    'ダブルクオーテーションでエスケープするフィールドがあるならTrue
    parser.HasFieldsEnclosedInQuotes = True
    '区切り文字前後の空白スペースを除去するならTrue
    parser.TrimWhiteSpace = True

    '=========================================
    'Parse開始
    '=========================================
    'ファイル終端まで繰り返す
    While Not parser.EndOfData
        '結果を入れるリスト(1行分)
        Dim ret_row As New List(Of String)

        '1行読み出す => 各列の配列になって取得できる
        Dim row As String() = parser.ReadFields()

        '各列を読み出し
        For Each field As String In row
            '各列分リストへ入れる
            ret_row.Add(field)
        Next
        '出来た1行分をリストへ入れる
        ret.Add(ret_row)
    End While

    Return ret
End Function

IO.Streamを指定

ファイル名ではなくIO.Streamを指定してやる.

こっちの方が外部IOが無い分, シンプルで良いと思う.

''' <summary>
''' CSVのIO.Streamを渡して解析し, 結果の2次元のリストを返す
''' </summary>
''' <param name="csvStream">解析するCSVのIOStream</param>
''' <returns>CSVの行列を含む2次元のリスト</returns>
Private Function LoadCSVFromStream(ByVal csvStream As IO.Stream) As List(Of List(Of String))
    '=========================================
    '結果返答用のリストを準備
    '=========================================
    Dim ret As New List(Of List(Of String))

    '=========================================
    'ファイル解析用にTextFieldParserを用意
    '=========================================
    Dim encoding As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
    Dim parser As New FileIO.TextFieldParser(csvStream, encoding)

    '=========================================
    'Parserの設定
    '=========================================
    '区切り文字形式指定
    parser.TextFieldType = FileIO.FieldType.Delimited
    'デリミタを指定(CSVなら, TSVならvbTab)
    parser.SetDelimiters(",")
    'ダブルクオーテーションでエスケープするフィールドがあるならTrue
    parser.HasFieldsEnclosedInQuotes = True
    '区切り文字前後の空白スペースを除去するならTrue
    parser.TrimWhiteSpace = True

    '=========================================
    'Parse開始
    '=========================================
    'ファイル終端まで繰り返す
    While Not parser.EndOfData
        '結果を入れるリスト(1行分)
        Dim ret_row As New List(Of String)

        '1行読み出す => 各列の配列になって取得できる
        Dim row As String() = parser.ReadFields()

        '各列を読み出し
        For Each field As String In row
            '各列分リストへ入れる
            ret_row.Add(field)
        Next
        '出来た1行分をリストへ入れる
        ret.Add(ret_row)
    End While

    Return ret
End Function

StringをIO.Streamへ変換してやれば文字列渡しでも使えるし.

''' <summary>
''' CSVのStringを渡して解析し, 結果の2次元のリストを返す
''' </summary>
''' <param name="csvStr">解析するCSVのString</param>
''' <returns>CSVの行列を含む2次元のリスト</returns>
Private Function LoadCSVFromString(ByVal csvStr As String) As List(Of List(Of String))
    'Encoding指定し, StringをStreamへ変換
    Dim encoding As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
    Dim stream As New IO.MemoryStream(encoding.GetBytes(csvStr))

    'Streamを2次元のリストにして返す
    Return LoadCSVFromStream(stream)
End Function

書き込み

読み込みに比べれば随分楽です.

''' <summary>
''' Streamに対してCSVListの内容をCSV形式で書き込みます
''' </summary>
''' <param name="stream">書き込み先Stream</param>
''' <param name="CSVList">書き込む内容の行/列の2次元List</param>
''' <param name="delimiter">区切り文字</param>
''' <returns>書き込み先Stream</returns>
Private Function WriteCSV(ByVal stream As IO.StreamWriter, CSVList As List(Of List(Of String)), ByVal delimiter As String) As IO.StreamWriter
    For i As Integer = 0 To CSVList.Count - 1
        Dim row As List(Of String) = CSVList(i)

        For k As Integer = 0 To row.Count - 1
            '列の値
            Dim col As String = row(k)

            'デリミタが含まれていればエスケープ
            If col.Contains(delimiter) = True Then
                'ダブルクオーテーションが含まれているか確認
                ' => 2重化してエスケープ
                If col.Contains("""") = True Then
                    col = col.Replace("""", """""")
                End If
                '両端にダブルクオーテーションを入れてエスケープ
                col = """" & col & """"
            End If

            '列の値を書き込み
            stream.Write(col)

            '最終列でなければデリミタ挿入
            If k <> row.Count - 1 Then
                stream.Write(delimiter)
            End If
        Next
        '最終行でなければ改行を書き込み
        If i <> CSVList.Count - 1 Then
            stream.Write(vbCrLf)
        End If
    Next

    Return stream
End Function

使う時はこんな感じ.

''' <summary>
''' 試しに書き込み
''' </summary>
Private Sub testCSVWrite()
    '=========================================
    'テスト用のデータ作成
    '=========================================
    Dim list As New List(Of List(Of String))

    Dim r1 As New List(Of String)
    r1.Add("abc")
    r1.Add("def")
    list.Add(r1)

    Dim r2 As New List(Of String)
    r2.Add("""abc""")
    r2.Add("def")
    list.Add(r2)

    Dim r3 As New List(Of String)
    r3.Add("test,string")
    r3.Add("""zxd,")
    list.Add(r3)

    '=========================================
    '書き込み
    '=========================================
    'エンコーディング指定
    Dim encoding As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
    '保存先パス
    Dim path As String = System.IO.Path.Combine(
        System.Environment.GetFolderPath(Environment.SpecialFolder.DesktopDirectory),
        "test.csv")
    '書き込み用のStreamWriterを準備
    '第一引数でパス指定
    Dim sw As New IO.StreamWriter(path, False, encoding)
    '書き込み
    WriteCSV(sw, list, ",")
    '閉じる
    sw.Close()
End Sub

StringとIO.Streamを相互変換する

String => IO.Stream

'Encoding指定し, StringをStreamへ変換
Dim str as String = "test"
Dim encoding As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
Dim stream As New IO.MemoryStream(encoding.GetBytes(str))

IO.Stream => String

'Encoding指定し, StreamをStringへ変換
Dim encoding As System.Text.Encoding = System.Text.Encoding.GetEncoding("Shift_JIS")
Dim stream As New IO.MemoryStream(encoding.GetBytes("Test String"))
Dim str As String = encoding.GetString(stream.ToArray())

ComboBoxコントロールに表示値と値を一度に設定する

データのDictionaryを作って, DataSourceにBindingしてやると楽.

''' <summary>
''' コンボボックスに値を設定する
''' </summary>
''' <param name="combo">値を設定するコンボボックスコントロール</param>
Private Sub setComboBox(ByVal combo As ComboBox)
    '=========================================
    '初期化
    '=========================================
    'コンボボックスの表示アイテムをクリア
    combo.Items.Clear()
    '表示値としてDataSourceの'Key'を利用
    combo.DisplayMember = "Key"
    '値としてDataSourceの'Value'を利用
    combo.ValueMember = "Value"

    '=========================================
    '設定するデータソースの準備
    '=========================================
    Dim dic As New Dictionary(Of String, Integer)
    dic("りんご") = 1  '表示値:りんご => 値:1
    dic("みかん") = 2  '表示値:みかん => 値:2
    dic("すいか") = 3  '表示値:すいか => 値:3

    'ダミー行が欲しい場合(未選択時の空白とか)は以下の様に入れとくと便利
    dic("") = -1 '表示値:空白(未設定) => 値:-1

    '=========================================
    'データソースをコンボボックスへ設定
    '=========================================
    combo.DataSource = New BindingSource(dic, Nothing)
End Sub

これをロードイベントとかで呼び出してやる

''' <summary>
''' フォームロード時イベント
''' </summary>
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load
    'ComboBox1を設定
    setComboBox(ComboBox1)
End Sub

CentOS7を使って雑にNATルータを作る

手っ取り早くNATルータが欲しくなった時にNICが複数あるLinuxマシンがあればラッキーだ.

CentOS7でやったことがなかったのでメモっておく.

nmcliをちゃんと使うべきなんだろうけど, 設定ファイルを直接触った.

1. ネットワークの設定

NICそれぞれに対して設定する.

特にNATとか関係なく普通に設定.

内側のネットワークにはGATEWAYを設定しない.

内側(/etc/sysconfig/network-script/ifcfg-eth0)

TYPE=Ethernet
BOOTPROTO=none
DEFROUTE=yes
PEERDNS=yes
PEERROUTES=yes
IPV4_FAILURE_FATAL=no
IPV6INIT=yes
IPV6_AUTOCONF=yes
IPV6_DEFROUTE=yes
IPV6_PEERDNS=yes
IPV6_PEERROUTES=yes
IPV6_FAILURE_FATAL=no
NAME=eth0
UUID=[なんかはいってる]
DEVICE=eth0
ONBOOT=yes
IPADDR=[内側のNATのIP]
PREFIX=24 # [内側ネットワークのマスク]

外側(/etc/sysconfig/network-script/ifcfg-eth1)

TYPE=Ethernet
BOOTPROTO=none
DEFROUTE=yes
PEERDNS=yes
PEERROUTES=yes
IPV4_FAILURE_FATAL=no
IPV6INIT=yes
IPV6_AUTOCONF=yes
IPV6_DEFROUTE=yes
IPV6_PEERDNS=yes
IPV6_PEERROUTES=yes
IPV6_FAILURE_FATAL=no
NAME=eth1
UUID=[なんかはいってる]
DEVICE=eth1
ONBOOT=yes
IPADDR=[外側ネットワークのNATのIP]
GATEWAY=[外側のゲートウェイのIP]
PREFIX=24  # [外側ネットワークのマスク]

2. ネットワークエラーにzoneを設定

firewalldにはzoneという概念があるそうで, デフォルトでうまく機能していたので今回はそれを使った.

内側(/etc/sysconfig/network-script/ifcfg-eth0)

...  # 一番下に追記した
ZONE=trusted

外側(/etc/sysconfig/network-script/ifcfg-eth1)

...  # 一番下に追記した
ZONE=external

3. アダプタを再起動

# ifdown eth0
# ifdown eth1
# ifup eth0
# ifup eth1

4. 一応firewall-cmdで確認

# firewall-cmd --list-all-zones

trustedだとなんでも許すので, 必要に応じてinternal使うんだろうな.

gitのfirst commitをビルドする

興味わいたのでやってみたけど意外とうまくいかなかったのでメモ.

ソース自体はgithubにミラーがあって, ここから手に入る.

ubuntu trustyの64bit環境でやった.

そのまま素直にビルドしようとすると以下のエラーが出た.

vagrant@vagrant-ubuntu-trusty-64:~/repo/git$ make
gcc -g   -c -o update-cache.o update-cache.c
In file included from update-cache.c:1:0:
cache.h:13:25: fatal error: openssl/sha.h: No such file or directory
 #include <openssl/sha.h>
                         ^
compilation terminated.
make: *** [update-cache.o] Error 1

libssl-devが入ってなくて怒られているっぽいので入れる.

vagrant@vagrant-ubuntu-trusty-64:~/repo/git$ sudo apt-get install libssl-dev

それでも怒られたのでMakefileを編集.

-lcryptoが無いとopenssl関連のビルドが通らず, -lzが無いとzlib関連が通らなかった.

LIBS= -lssl -lcrypto -lz

これでmakeすると(warnningがいっぱい出るが)ビルドできた.